Lệnh trong iMacro P2

Posted on at


Phần tiếp theo trong nhóm các câu lệnh cơ bản của iMacro gồm có 12 lệnh tất cả. Như tôi viết ở phần 1 thì đây là những câu lệnh thường dùng trong iMacro, hãy nắm bắt nó một cách dễ dàng. Chúng ta bắt đầu nhé !

 

11.REFRESH

Thực hiện lệnh “REFRESH” tương tự như việc chúng ta nhấn F5 để load lại trang web của tình duyệt

Ví dụ:

SET !FILESTOPWATCH myresults.csv
STOPWATCH ID=total1
URL GOTO=http://www.iopus.com
STOPWATCH ID=total1
‘Clear cache and reload
CLEAR
STOPWATCH ID=total2
REFRESH
STOPWATCH ID=total2
‘Clear cache and reload
CLEAR
STOPWATCH ID=total3
REFRESH
STOPWATCH ID=total3

12.SAVEAS

Với câu lệnh này bạn có thể lưu lại website hiện hành dưới dạng CPL, HTM, TXT, EXTRACT hoặc dưới dạng ảnh chụp toàn bộ trang web PNG, JPEG.

Đây là một lệnh quan trọng, nó rất hữu ích trong nhiều công việc, hãy nhớ nằm lòng nó.

Cú pháp:  SAVEAS TYPE=(CPL|HTM|TXT|EXTRACT|PNG|JPEG) FOLDER=folder_name FILE=file_name

Mặc định đường dẫn lưu vào thư mục Downloads của iMacro.

Ví dụ:

‘*.htm + thư mục dữ liệu của trang
SAVEAS TYPE=CPL FOLDER=* FILE=+{{!NOW:ddmmyyyy}}

‘*.htm
SAVEAS TYPE=HTM FOLDER=* FILE=+{{!NOW:ddmmyyyy}}

‘*.txt
SAVEAS TYPE=TXT FOLDER=* FILE=+{{!NOW:ddmmyyyy}}

‘*.csv
SET !EXTRACT 1,2,3
SAVEAS TYPE=EXTRACT FOLDER=* FILE=+{{!NOW:ddmmyyyy}}

‘*.png
SAVEAS TYPE=PNG FOLDER=* FILE=+{{!NOW:ddmmyyyy}}

‘*.jpeg
SAVEAS TYPE=JPEG FOLDER=* FILE=+{{!NOW:ddmmyyyy}}

13.SAVEITEM

Khi bạn click vào đường dẫn trực tiếp tới một tập tin nào đó và bạn muốn lưu nó về máy tính với tên … , “SAVEITEM” sẽ giúp bạn thực hiện việc này một cách tự động và hết sức đơn giản.

Dowload các tập tin và lưu vào thư mục Downloads

Ví dụ 1:  Dowload ảnh từ site page

URL GOTO=http://demo.imacros.net/Automate/Images
TAG POS={{!loop}} TYPE=IMG ATTR=HREF:http://*.jpg
ONDOWNLOAD FOLDER=* FILE=+_image_{{!NOW:yyyymmdd_hhnnss}}
TAG POS=1 TYPE=IMG ATTR=HREF:http://*.jpg CONTENT=EVENT:SAVEITEM
WAIT SECONDS=3

Ví dụ 2:  Dowload PDF file

‘1st Download (small file)

URL GOTO=http://demo.imacros.net/Automate/PDFDemo
TAG POS=1 TYPE=A ATTR=TXT:*View<SP>small<SP>PDF<SP>Document*
ONDOWNLOAD FOLDER=* FILE=+_{{!NOW:yyyymmdd_hhnnss}}
SAVEITEM

‘2nd Download (same as #1 but larger file)

URL GOTO=http://demo.imacros.net/Automate/PDFDemo
TAG POS=1 TYPE=A ATTR=TXT:*View<SP>iMacros<SP>Case<SP>Study*
ONDOWNLOAD FOLDER=* FILE=+_{{!NOW:yyyymmdd_hhnnss}}
TAB T=1
SAVEITEM

14.SCREENSHOT

Cú pháp:  SCREENSHOT TYPE=(PAGE|BROWSER) FOLDER=folder_name FILE=file_name

Tập tin download được sẽ lưu vào thư mục Downloads.

Ví dụ 1: Page=Chỉ chụp home page || Browser= Chụp trình duyệt

URL GOTO=http://www.iopus.com/imacros/home/v9/home.asp
SCREENSHOT TYPE=Page FOLDER=* FILE=*
SCREENSHOT TYPE=Browser FOLDER=* FILE=*
TAB T=1
SAVEITEM

15.SEARCH

Cú pháp:  SEARCH SOURCE=(TXT|REGEXP) IGNORE_CASE=YES EXTRACT=$1

Ví dụ: Tìm Tracker GA

URL GOTO=http://imacros.net/
SEARCH SOURCE=REGEXP:”ga\\(‘create’, ‘([^’]+)’, ‘imacros.net’\\)” EXTRACT=”Tracker is $1″
PROMPT {{!EXTRACT}}

***Lưu ý: REGEXP tôi đề cập ở đây tương tự như REGEXP của Javascript.

16.SET

Cú pháp:  SET var value

var: Biến có sẵn của iMacro !VAR0 –> !VAR9 hoặc biến do người dùng đặt {{var1}}, {{var2}}

Ví dụ:

SET myDelay 10
WAIT SECONDS={{myDelay}}

SET !VAR1 Hello<SP>World
PROMPT {{!VAR1}}

SET !VAR1 “Hello World”
PROMPT {{!VAR1}}

SET !TIMEOUT_PAGE 360
SET !TIMEOUT_STEP 10

17.STOPWATCH

Giải thích như thế nào với các bạn bây giờ. Nó như là một cái đồng hồ bấm giờ, chỉ khác ở trong iMacro thì các bạn bấm giờ, đo thời gian chạy code giữa 2 điểm STOPWATCH có ID giống nhau.

Cú pháp:  STOPWATCH ID=id

Ví dụ: Lưu dữ liệu thời gian tới thư mục Dowloads.

STOPWATCH ID=Total
‘Measure load time for first page
STOPWATCH ID=Firstpage
URL GOTO=http://demo.imacros.net/Automate/StopWatchDemo
STOPWATCH ID=Firstpage

TAG POS=1 TYPE=A ATTR=HREF:http://demo.imacros.net/Automate/AutoDataEntry
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/Automate/FormSubmit ATTR=NAME:fname CONTENT=Tom
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/Automate/FormSubmit ATTR=NAME:lname CONTENT=Testerr
‘Measure server reaction on submit
STOPWATCH ID=SubmitData
TAG POS=1 TYPE=BUTTON:SUBMIT FORM=ID:demo ATTR=TXT:Submit
STOPWATCH ID=SubmitData

STOPWATCH ID=Total

18.TAB

Thao tác với các TAB của trình duyệt, mở TAB mới, đóng TAB cũ, ..

Cú pháp:  TAB (T=n|OPEN|CLOSE|CLOSEALLOTHERS)

Ví dụ:

TAB OPEN
WAIT SECONDS=1
TAB T=2
WAIT SECONDS=1
TAB CLOSE
WAIT SECONDS=1
TAB OPEN
WAIT SECONDS=1
TAB OPEN
WAIT SECONDS=1
TAB OPEN
WAIT SECONDS=1
TAB T=4
WAIT SECONDS=1
TAB CLOSEALLOTHERS
WAIT SECONDS=1

19.TAG

Đây là lệnh mà các bạn sẽ sử dụng nhiều nhất trong quá trình viết code iMacro. Lệnh TAG có thể nó nói là biến hoá không lường trong code iMacro. Hãy để ý tới nó ..

Cú pháp:  TAG POS=n TYPE=type [FORM=form] ATTR=attr [CONTENT=some_content]

Ví dụ:

URL GOTO=https://accounts.google.com/SignUp?service=mail&continue=https%3A%2F%2Fmail.google.com%2Fmail%2F&hl=vi
TAG POS=1 TYPE=INPUT:TEXT FORM=NAME:createaccount ATTR=NAME:LastName CONTENT=demo
TAG POS=1 TYPE=INPUT:TEXT FORM=NAME:createaccount ATTR=NAME:FirstName CONTENT=demo

20.URL

Bạn muốn chuyển tới một trang web khác mà không cần click vào link, không cần thao tác. Quá dễ, hãy sử dụng lệnh URL dưới đây ..

Cú pháp: URL GOTO=some_URL
Ví dụ:

URL GOTO=http://www.iopus.com
TAB OPEN
TAB T=2
URL GOTO=http://www.google.com

21.VERSION

Lệnh này thực ra cũng không quá quan trọng, thường thì không có nó cũng chả làm sao, mà có nó thì cũng không mang lại gì. Lệnh này khai báo phiên bản của chương trình iMacro. Hãy thử Rec lại một thao tác nào đó, iMacro sẽ tự tạo ra dòng này ở ngay đầu file *.iim hoặc bạn cũng có thể tự code như thế này:

Cú pháp: VERSION BUILD=<version number>

Ví dụ:

VERSION BUILD=8890130 RECORDER=FX

22.WAIT

Sử dụng lệnh này để đợi chờ một khoảng thời gian không làm gì trước khi thực hiện câu lệnh tiếp theo

Cú pháp:  WAIT SECONDS=(n|#DOWNLOADCOMPLETE#)

Ví dụ:

URL GOTO=http://www.iopus.com
WAIT SECONDS=10
URL GOTO=http://wiki.imacros.net/Main_Page

Lời kết

Chúc các bạn một ngày vui vẻ và làm việc hiệu quả !

Còn vấn đề nào mà chưa tự giải quyết được không ?. Bằng cách để lại vấn đề của bạn tại chuyên mục bình luận. Mọi người sẽ cùng xử lý giúp bạn đấy.



About the author

mixloves

Đẹp nhất, tốt nhất, hay nhất, tuyệt vời nhất dành cho bạn ! Hãy tận hưởng điều đó ..

Subscribe 0
160